;------------------------------------------------------------------
;+
; NAME:
;	SUNCLIST
; PURPOSE:
;	This procedure makes a list of the Sun center values found
;	for a set of BBSO VMGs which have been processed with
;	CENTERE or similar procedures.
; CATEGORY:
;	POLAR
; CALLING SEQUENCE:
;       SUNCLIST,gfnam
; INPUTS:
;	gfnam = file name(s) for examination, may include wild cards.
; KEYWORD PARAMETERS:
;       list = file name for output, if not given, output only to screen.
; OUTPUTS:
;	Prints FITS info to screen.
; COMMON BLOCKS:
; NOTES:
; MODIFICATION HISTORY:
;	J. Varsik,	03 Jan. 1996
;-
;-------------------------------------------------------------------

pro sunclist,gfnam,list=tlist

    ; Display IDL header if help is required.
    if (keyword_set(help)) then begin
      get_idlhdr,'sunclist.pro'
      goto,finishup
    endif

    out = 0
    if (keyword_set(tlist)) then begin
      listnam = tlist
      out = 1
    endif
    ; Get array of file names
    fnarr = FINDFILE(gfnam,count = fcount)
    if (fcount eq 0) then goto,finishup

    ; Print header
    PRINT,'    filename         date     time       cenx     ceny    radius'

    if (out eq 1) then begin
       olun = 2
       OPENW,olun,listnam
       PRINTF,olun,$
          '    filename         date     time       cenx     ceny    radius'
    endif

    ; Loop over files
    for i = 0, fcount-1 do begin
      fn = fnarr(i)
      ; open file, read header.
      flun = 1
      OPENR,flun,fn
      FXHREAD,flun,fheader,fstat
      if (fstat ne 0) then PRINT,'error reading header of file ',fn
      CLOSE,flun
      
      time = FXPAR(fheader,'TIME-OBS')
      date = FXPAR(fheader,'DATE-OBS')
      cenx = FXPAR(fheader,'CENTERX')
      ceny = FXPAR(fheader,'CENTERY')
      rad  = FXPAR(fheader,'RADIUS')
      PRINT,FORMAT='(A20," ",A," ",A," ",F10.2," ",F10.2," ",F10.2)',$
          fn,date,time,cenx,ceny,rad
      if (out eq 1) then begin
        PRINTF,olun,$
          FORMAT='(A20," ",A," ",A," ",F10.2," ",F10.2," ",F10.2)',$
          fn,date,time,cenx,ceny,rad
      endif
    endfor
    
    if (out eq 1) then CLOSE,olun

    finishup:

    return
end